Ejecuta la Funcion Query
FUNCIÓN QUERY EN GOOGLE SHETS
La Función Query requiere de una base de datos y una consulta que puede estar escrita en lenguaje SQL ademas de esto recuerda que debes tener conocimientos previos para poder usarla, sin embargo en este vídeo se te dan las sentencias para que puedas emplearla de manera mas eficiente y sobre todo de forma mas rápido.
Para esto usaremos una base de datos pequeña con un reducido numero de campos para que de esta manera puedas ver como funciona. Para iniciar este ejemplo colocamos nuestra base de datos en una hoja y en una segunda hoja emplearemos la función Query: de la siguiente manera.
Una vez ingresada la función Query seleccionamos los datos tal y como se muestra en la consulta de la función, esto funcionara como nuestra matriz de datos, que se encuentra ubicada en la hoja1 denominada base de datos.
De este modo es como debe quedar tú formula Query y como podaras darte cuenta te trae todos los campos que tienes en la hoja anterior.
=QUERY('Base de datos'!A1:E321;"SELECT*")
Si quisieras reducir el numero de datos, solo colocamos una instrucción llamada Limit 10 (en este caso colocamos el numero para que esa sea la cantidad de datos que te traiga).
=QUERY('Base de datos'!A1:E321;"SELECT* Limit 10")
En este punto te darás cuenta de que se reflejan los 10 primeros resultados , sin contar los títulos.
También podemos hacer uso de la función OFFSET para contar de el número de registros indicados hacia abajo.
=QUERY('Base de datos'!A1:E321;"SELECT* OFFSET 10")
Hasta aquí te mostramos como traer todos y cada uno de los datos, sin embargo también esta la opción de traer cierto numero de columnas, esto únicamente con “llamar la columna correspondiente” ejemplo: A,B,C,D.
=QUERY('Base de datos'!A1:E321;"SELECT A,B,C,D")
Dando otro nombre
Para continuar, podemos organizar de manera alfabética con la fórmula de ORDER BY, para este ejemplo usaremos de apoyo la columna A en donde se encuentra el RFC en nuestra hoja de base de datos.
=QUERY('Base de datos'!A1:E321;"SELECT A,B,C,D ORDER BY A")
Otra de las maneras de usar la función Query
Puedes usarla con funciones del tipo matemáticas en este caso usaremos la función de SUMAR.
=QUERY('Base de datos'!A1:E321;"SELECT A,B,SUM(C) GROUP BY A,B ORDER BY A")
Insertar la fórmula de Sum dentro de Query es el equivalente al haber usado si.conjunto, suma total y ademas de eso te trae los datos exactos de las columnas que señalas.
Te mostraré otras maneras de usar la función Query.
=QUERY('Base de datos'!A1:E321;"SELECT A,B,MAX(C)GROUP BY A,B ORDER BY A")
Valores máximos de la base de datos.
=QUERY('Base de datos'!A1:E321;"SELECT A,B,MAX(E)GROUP BY A,B ORDER BY A")
Esta formula editada nos traerá los datos máximos de las fechas.
Continuando, ordenamos los datos de manera ascendente y descendente de la siguiente manera.
=QUERY('Base de datos'!A1:E321;"SELECT A,B,MAX(E)GROUP BY A,B ORDER BY MAX(E) ASC")
=QUERY('Base de datos'!A1:E321;"SELECT A,B,MAX(E)GROUP BY A,B ORDER BY MAX(E) DESC")
Ahí mismo podemos cambiar la función de max y usar la de AVG, que es la función de promedio.
=QUERY('Base de datos'!A1:E321;"SELECT A,B,AVG(C)GROUP BY A,B ORDER BY A DESC")
Cálculos para la determinación del IVA
=QUERY('Base de datos'!A1:E321;"SELECT A,B, SUM(C), SUM(C)*0.16 GROUP BY A,B")
De esta otra manera calculamos el total y el iva.
=QUERY('Base de datos'!A1:E321;"SELECT A,B, SUM(C)*0.16, SUM(C)*1.16 GROUP BY A,B")
Hasta este punto te hemos mostrado como utilizar operaciones básicas de utilidad y ahora te mostraremos como podemos usar la función where que es un equivalente a los filtros en Excel, para esta parte no olvides seleccionar el dato que quieras traer. En este caso usaremos "IEL030313JX9".
=QUERY('Base de datos'!A1:E321;"SELECT A, B WHERE A=""IEL030313JX9""")
También le podemos dar otro uso a estos filtros como la función like que nos traerá todos los registros "similares" o parecidos a todo aquello que nosotros coloquemos entre ""%%""
=QUERY('Base de datos'!A1:E321;"SELECT A, B WHERE B LIKE ""%S DE R.L.%""")
Hagamos un filtro por datos numéricos en intervalos.
=QUERY('Base de datos'!A1:E321;"SELECT A,B,C,D WHERE D>=100 AND D<=1100 ORDER BY D")
Intervalos con datos alfanuméricos.
=QUERY('Base de datos'!A1:E321;"SELECT A,B,C,D WHERE A=""IEL030313JX9"" OR D=""DFO060118MU5"" ORDER BY A")
Para concluir podrás darte cuenta que la función Query puede llegar a ser bastante útil pues nos trae encabezados, podemos ordenar, hacer operaciones, conjuntos entre otros.
Te dejo un enlace de Google sheets con los datos de este ejercicio para que puedas trabajar en ella.
